Come gestire gli OKR su Excel

In questa guida vediamo come creare e gestire un template su Excel dedicato agli OKR. Potrai inserirli singolarmente e rivederli poi in una visualizzazione personalizzata!

Puoi scaricare il file cliccando sul pulsante, se vuoi scoprire di più sugli OKR e su come è stato creato il file, continua a leggere!

Qui c'è invece il recap, sempre inserito nel file, per tenere d'occhio tutti gli OKR in una visione di insieme:

Non ho inserito, volutamente, le iniziative da seguire per arrivare ai Key Result dato che rischiano di complicare molto il file, l'idea è quella di avere uno strumento rapido e immediato per comunicare le singole priorità per poi approfondirle nel dettaglio in seconda battuta.

Che cosa sono gli OKR

Gli OKR (Obiettivi e Key Results) sono un sistema di gestione delle prestazioni utilizzato per definire e monitorare gli obiettivi aziendali e i risultati chiave. Si tratta di una metodologia efficace per migliorare la concentrazione, la collaborazione e la motivazione del team, nonché per garantire che tutti lavorino verso obiettivi comuni. Si è iniziato a parlare di OKR a partire dalle teorie di John Doerr, che ha introdotto il tema in Measure What Matters, un libro ti consiglio assolutamente di recuperare nel caso ti interessi l'argomento.

In grandissima sintesi, il tema fondante degli OKR è la coabitazione di obiettivi (O) e key result (KR) per definire e tracciare obiettivi e misurare il progresso. Gli OKR consistono di obiettivi ambiziosi ma specifici che vengono definiti insieme ai risultati chiave che dimostrano il progresso verso quegli obiettivi. Questo approccio aiuta a mantenere l'attenzione su ciò che è importante e a sincronizzare i team e l'intera organizzazione verso una direzione comune. In una singola vista, è possibile inserire un obiettivo da raggiungere tramite il raggiungimento di risultati (misurabili) che semplifica notevolmente anche la parte di riassunto verso terzi.

Numerose statistiche sugli OKR sono disponibili a questo link, nel caso volessi approfondire. Ho trovato interessante leggere che ben l'83% delle società intervistate concordano nel dire che gli OKR hanno un impatto positivo sulla loro organizzazione, lato strategia e tattica sono sicuramente un tool molto valido. Purtroppo la loro implementazione non è sempre così semplice - benchè la spiegazione sia intuitiva, non sempre si arriva velocemente a creare una struttura dinamica in grado di accomodare la parte operativa.

Vediamo quindi come creare da zero una struttura per creare e monitorare gli OKR - la versione è compatibile con Excel 365, quindi se non possiedi questa versione puoi comunque utilizzare il file con la versione online di Excel che è completamente gratuita. Attenzione a caricare questo file per poi aprirlo con Google Sheets, dato che numerose formule salterebbero e quindi il file non sarebbe più utilizzabile, ti consiglio di usare Onedrive in modo da poter usare Excel online ed evitare problemi.

Come creare e tracciare gli OKR su Excel

Ogni OKR vive di vita propria, quindi su Excel risulta più complesso del previsto gestirli. Il singolo obiettivo sovrasta i key results, richiedendo quindi una struttura ad hoc per la gestione del singolo obiettivo. Vediamo nel dettaglio come è creato il file:

Come indicare gli obiettivi per gli OKR su Excel

Vi sono parti che abbiamo inserito per gli obiettivi sono le seguenti:

• GOAL: qui metteremo il numero del goal che ci siamo prefissati
• TESTO: qui inseriremo invece una breve descrizione testuale del nostro obiettivo
• PROGRESSO: questo valore è calcolato in automatico, prendendo i dati dai key result che saranno inseriti successivamente
• ENTRO: questa è la deadline che possiamo inserire in autonomia
• GIORNI: questi sono i giorni rimanenti prima della deadline, anch'essi calcolati in automatico

Le formule utilizzate sono specifiche per alcuni di questi punti, vediamole nel dettaglio:

=SE(SOMMA(TBL_GOAL1[Importanza])<>1;"Importanza %";
SOMMA(TBL_GOAL1[Importanza]*TBL_GOAL1[Progresso]))

Qui utilizziamo la funzione SE per controllare se la somma dei valori nella colonna "Importanza" della tabella TBL_GOAL1 non è uguale a 1. Se la condizione è vera, la formula restituirà la stringa "Importanza %". Altrimenti, la formula esegue una moltiplicazione e una somma dei valori nella colonna "Importanza" moltiplicati per i valori nella colonna "Progresso". Il senso di questa formula è indicare all'utente se c'è un errore, dato che le percentuali non possono superare il valore 1 (100%) nell'importanza. Se invece il totale è correttamente 1, allora facciamo una media ponderata dei valori moltiplicando l'importanza per il suo progresso.

=LET(deadline;I5-OGGI(); SE(deadline<=0;"OVER";deadline))

In questo caso utilizziamo la funzione LET per assegnare il valore restituito dalla funzione SE ad una variabile chiamata "deadline".

La funzione I5-OGGI() sottrae la data corrente (ottenuta tramite la funzione OGGI()) dalla data contenuta nella cella I5. Il risultato viene assegnato alla variabile "deadline". Questa è una procedura comoda nel caso il valore si ripeta varie volte nei calcoli seguenti, come in questo caso.

La funzione SE controlla infatti se il valore di "deadline" è minore o uguale a 0. Se la condizione è vera, la formula restituirà la stringa "OVER". Altrimenti, la formula restituirà il valore di "deadline", cioè la differenza fra la data di oggi e la scadenza.

=CERCA.X(I4;TBL_RANKING[VALORE];TBL_RANKING[ICONA];"";-1)

Vogliamo restituire un'icona a seconda del nostro risultato, preso dalla tabella TBL_RANKING che si trova sul foglio LIST. In questo caso ci accorre in aiuto CERCA.X, che cerca il valore contenuto nella cella I4 all'interno della colonna "VALORE" della tabella TBL_RANKING. Se il valore viene trovato, la formula restituirà il valore corrispondente nella colonna "ICONA". Se il valore non viene trovato, la formula restituirà un valore vuoto (""). La stringa "-1" indica che la funzione CERCA.X restituisce il valore corrispondente o quello più piccolo, questo è simile alla procedura che magari hai incrociato in passato lavorando con CERCA.VERT e VERO.

=CERCA.X(I4;TBL_RANKING[VALORE];TBL_RANKING[TESTO];"";-1)

La formula per trovare un breve commento è praticamente la stessa, varia solamente la parte di restituzione (dove anzichè ICONA troviamo TESTO).

Come indicare i key result per gli OKR su Excel

I singoli KR possono essere inseriti in una tabella dedicata, dato che abbiamo una coerenza interna: a ogni riga, corrisponde un key result.

In questo caso la tabella è composta così:

• KR: questo è il numero di KR per il singolo obiettivo, che si aggiornerà in automatico
• DESCRIZIONE: qui inseriamo la nostra descrizione del singolo KR
• OWNER: qui definiamo chi sarà l'owner del KR, che è un ruolo molto importante e di responsabilità
• IMPORTANZA: qui mettiamo, da 0 a 1, qual è l'importanza relativa del KR rispetto all'obiettivo
• VALORE ATTUALE: qui inseriamo il valore attuale per poi calcolare il progresso.
• GOAL: il goal viene preso in automatico dalla descrizione
• LESS / MORE: se vogliamo che il valore sia superiore al Goal, allora sarà More. Altrimenti Less
• PROGRESSO: questo è un calcolo automatico per verificare a che punto siamo con il nostro KR

Le formule si rendono necessarie per scalare il nostro file, in particolare:

=SE(VAL.VUOTO([@Descrizione]);"";CONCAT("KR";RIF.RIGA()-RIF.RIGA(TBL_GOAL1[[#Intestazioni];[KR]])))

Dato che i KR sono progressivi, dobbiamo creare un escamotage per numerarli singolarmente. Se non abbiamo una descrizione per il singolo KR, avremo semplicemente un valore vuoto. Altrimenti, la formula utilizza la funzione CONCAT per unire la stringa "KR" con il numero calcolato come la differenza tra la riga corrente e la riga dell'intestazione "KR" nella tabella TBL_GOAL1.

La tabella TBL_GOAL1 è la prima che abbiamo sul nostro foglio, sempre per una questione di coerenza interna. La formula sarà uguale anche nelle tabelle successive, ma varierà TBL_GOAL1 con il nome di tabella che scegliamo noi.

=NUMERO.VALORE(TESTO.UNISCI("";VERO;SE.ERRORE((STRINGA.ESTRAI([@Descrizione];RIF.RIGA(INDIRETTO("1:"&LUNGHEZZA([@Descrizione])));1)*1);"")))

Questa è la parte del file meno comprensibile e che potresti voler rimuovere. In sostanza ho dato per scontato che nella descrizione del KR ci sia solamente un numero. In questo caso, la formula concatena con TESTO.UNISCI tutti i caratteri che trova nella descrizione per poi restituire unicamente i valori numerici. Andando più nel dettaglio, STRINGA.ESTRAI estrae i singoli caratteri all'interno della cella e poi con le formule RIF.RIGA e INDIRETTO ci permette di creare un array dinamico dal quale estrarre poi le singole informazioni, moltiplicate per 1 - NUMERO.VALORE poi ci restituisce unicamente i valori numerici, evitando i testi.

La funzione è corretta se c'è solo un valore numerico, però tu avessi una descrizione con vari numeri all'interno (del tipo "Ottenere 50 clienti con almeno 300K di fatturato") il risultato sarebbe 50300. In questo caso puoi semplicemente togliere la formula all'interno della tabella e inserire i valori a mano.

=LET(val;SE([@[Less / More]]="More";[@[Valore Attuale]]/[@Goal];[@Goal]/[@[Valore Attuale]]);SE(val>=1;1;val))

Alcuni dei KR potrebbero essere corretti se il risultato ottenuto è inferiore al goal: ad esempio meno del 10% di clienti che abbandonano la piattaforma, meno di 300 resi e così via. Less significa che il KR è realizzato con un valore inferiore a quello indicato come goal - More invece significa che il KR è realizzato con un valore superiore a quello del goal, sicuramente il caso più comune che incontreremo anche nei nostri OKR.

Vediamo come varia la formula a seconda di Less o More:

• Se c'è More, la formula esegue una divisione tra il valore della cella "Valore Attuale" e il valore della cella "Goal"
• Altrimenti, la formula esegue una divisione tra il valore della cella "Goal" e il valore della cella "Valore Attuale"

Nella seconda parte la formula indica che SE val fosse maggiore o uguale a 1, il risultato sarebbe soddisfatto - ad esempio se indico che "Voglio 100 clienti" e ne ottengo 300, sicuramente sarà verificato e quindi possiamo inserire semplicemente 100% anzichè 300%, dato che non avrebbe molto senso. Questo è il tipico caso More. Se invece non siamo ancora a 100%, la formula indicherà il rapporto fra goal e valore attuale.

Tutta la parte di note e commenti può essere modificata come preferisci, magari può tornare utile per discutere con il tuo team di alcuni dei KR nello specifico.

Come rivedere gli OKR nel loro complesso su Excel

Si rende necessaria la creazione di una visione d'insieme, che realizziamo sul foglio RECAP. In questo caso la formula fondamentale è solamente una:

=FILTRO(INSERIMENTO!B:I;(VAL.NUMERO(RICERCA("KR";REVIEW!B:B))+(VAL.NUMERO(RICERCA("GOAL";REVIEW!B:B))));"")

La funzione FILTRO utilizza una condizione composta per determinare quali righe devono essere incluse nel risultato, prendendo le colonne da B a I del foglio INSERIMENTO.

La combinazione VAL.NUMERO(RICERCA ci permette di cercare se all'interno di una certa cella sia presenta una stringa di testo. In particolare, la prima parte della condizione, VAL.NUMERO(RICERCA("KR";REVIEW!B:B)), utilizza la funzione RICERCA per cercare la stringa "KR" all'interno della colonna B della cartella "REVIEW". La funzione RICERCA restituisce il numero di riga in cui è stata trovata la stringa, mentre la funzione VAL.NUMERO converte il valore restituito da RICERCA in un valore numerico o in 0 se il valore è un errore. Praticamente la stessa procedura viene replicata ma questa volta cercando "GOAL" all'interno della stringa. Considera sempre che i singoli test valgono come se fossero un 1, che viene equiparata alla condizione vera - mentre con 0 sarebbero falsi.

La condizione complessiva, (VAL.NUMERO(RICERCA("KR";REVIEW!B:B))+(VAL.NUMERO(RICERCA("GOAL";REVIEW!B:B)))), somma i valori numerici restituiti da entrambe le parti. La condizione che stiamo cercando è una condizione O, dove ci è sufficiente che almeno una delle due condizioni sia vera, ovvero pari a 1. Se una delle stringhe viene trovata, il valore numerico restituito sarà maggiore di 0, e la riga corrispondente verrà inclusa nel risultato. Se entrambe le stringhe non vengono trovate, il valore numerico restituito sarà 0 e nessuna riga verrà inclusa nel risultato. La stringa vuota "" nella terza parte della funzione FILTRO indica di restituire un valore vuoto qualora non vi fossero righe inserite nel nostro sottinsieme.

Se ti stai chiedendo come mai i valori appaiano con colori diversi e con le righe, queste sono delle regole di formattazione condizionale che vedi riassunte qui nel pannello. In sostanza:

• Quando la cella della colonna B è pari a "KR", allora vogliamo il testo in grassetto dalla colonna B alla I. Queste sono le nostre intestazioni per la singola tabella
• Se il valore "KR" è contenuto nella cella della colonna B, allora vogliamo il testo in corsivo. Quindi vedremo i singoli KR in corsivo
• La barra dei dati funziona solamente sulla colonna I, in modo da darci una rappresentazione immediata dei singoli OKR
• Se la cella della colonna B contiene "GOAL", allora vogliamo che sia in blu, grassetto e in corsivo. Mettiamo anche i bordi in alto e in basso, in modo da chiarire ancora meglio che questo è il "GOAL" principale

Come inserire i valori di soglia per i singoli KR su Excel

Abbiamo una tabella dedicata, chiamata TBL_RANKING, per indicare i valori soglia per indicare se i valori indicati siano accettabili o meno. Ho inserito anche delle icone usando una formula:

=CARATT.UNI(10062)

Questa formula di Excel utilizza la funzione CARATT.UNI per restituire il carattere Unicode corrispondente al codice 10062. Il codice 10062 rappresenta il simbolo di check ✓ nella tabella dei caratteri Unicode, allo stesso modo ho inserito anche le altre 2. Puoi chiaramente scegliere quelle che preferisci, qui ne trovi un'ampia collezione. L'opposto sarebbe possibile con la funzione UNICODE, troveremmo in questo caso il carattere Unicode a partire da un simbolo specifico.

Consideriamo che, per gli OKR, già raggiungere 60-70% di quanto ci siamo prefissati è un risultato ottimo, dato che sono traguardi in genere decisamente sfidanti.

Come utilizzare il file OKR su Excel

Ho creato una struttura flessibile, dove puoi inserire il numero di obiettivi che preferisci. Ogni obiettivo ha una sua tabella dedicata, quindi se volessi aggiungerne degli altri ti basterebbe copiare le righe dal goal all'ultimo key result per poi aggiungerle sotto all'ultimo compilato.

A quel punto, ti consiglio di agire così:

• Modifica, prima di tutto, il goal. Metti un numero progressivo e un titolo "parlante"
• Rivedi la deadline, aggiornandola
• Rinomina la tabella che contiene i singoli KR
• Rivedi i singoli KR. Cambia la descrizione, il valore attuale e l'importanza per singolo KR

Spero che il file ti sia utile, puoi personalizzarlo come preferisci e per scaricarlo, puoi cliccare sul pulsante!