Creare grafico bolle Excel

In questa guida vediamo come creare un grafico a bolle con Excel. Prenderemo alcuni dati relativi a giocatori del Milan (Goal, Assist, Voto medio) per poi realizzare una piccola dashboard.

Vediamo prima di tutto quali siano gli elementi di un grafico a bolle su Excel:

• X: qui inseriamo i valori per le ascisse (l'asse X è quello che si sviluppa in orizzontale)
• Y: qui inseriamo i valori per le ordine (l'asse Y che quello che si sviluppa in verticale)
• Dimensione della bolla: qui scegliamo il valore che preferiamo, la dimensione relativa determinerà quanto saranno grandi le singole bolle

Per utilizzare questo grafico, abbiamo quindi bisogno di 3 diverse dimensioni. Se vuoi scoprire come crearlo da zero, continua pure nella lettura - altrimenti puoi scaricare la versione finale da qui:

NB: il file è compatibile con Excel 365 oppure con Excel online, con versioni precedenti non funzionerà. La parte principale, se non hai mai creato un grafico a bolle, è questa iniziale.

Come creare un grafico a bolle con colori diversi su Excel

Utilizzare colori diversi per le singole bolle può risultare complicato, dato che in realtà la regola principale è che ad ogni serie di dati corrisponde un colore. Per questo motivo, se avessimo 30 nazioni da analizzare e volessimo inserire un colore diverso per ognuna di loro, dovremmo avere ben 30 serie di dati.

Generalmente, abbiamo quindi bolle tutte dello stesso colore - ma in questo caso vogliamo che, come da immagine:

• I giocatori con più reti che assist abbiano la bolla rossa
• I giocatori con più assist che reti abbiano la bolla nera
• I giocatori con un numero uguale di reti e assist abbiano la bolla grigia

In questo caso ci servono quindi 3 serie di dati diverse - alle quali aggiungeremo un'ultima serie per il focus sul singolo giocatore.

La tabella di partenza si chiama TBL_GIOCATORI, questo ci aiuterà moltissimo per la parte di calcolo.

Separare i giocatori velocemente è possibile utilizzando la funzione FILTRO, in particolare:

=FILTRO(TBL_GIOCATORI;TBL_GIOCATORI[GOAL]>TBL_GIOCATORI[ASSIST])

Questa formula ci restituisce l'intera tabella unicamente per i giocatori che abbiano più goal che assist

=FILTRO(TBL_GIOCATORI;TBL_GIOCATORI[GOAL]=TBL_GIOCATORI[ASSIST])

Questa formula ci restituisce l'intera tabella considerando i giocatori che abbiano lo stesso numero di goal e assist

=FILTRO(TBL_GIOCATORI;TBL_GIOCATORI[GOAL]<TBL_GIOCATORI[ASSIST])

L'ultimo cluster che ci manca è quello dei giocatori con più assist che goal, la formula è praticamente la stessa per tutti e 3 i casi ma cambia solamente l'elemento di confronto

Come rendere un grafico a bolle dinamico su Excel

Vogliamo porre l'attenzione su uno specifico giocatore, a seconda di quello che seleziona l'utente con lo slicer / filtro dati. Questa sarà la nostra quarta serie di dati da inserire sul grafico. Per creare il focus utilizziamo un trucco già visto nella guida per creare un grafico dinamico su Excel. In sostanza:

• Prendiamo tutti i nomi dei giocatori (volendo possiamo utilizzare la funzione UNICI)
• Inseriamo i nomi dei giocatori in una nuova tabella
• Inseriamo, nella colonna VALORE, il calcolo =SUBTOTALE(3;[@GIOCATORI])

Creando lo slicer (selezionando la tabella > Inserisci filtro dati) a partire da questa nuova tabella, potremo visionare velocemente il profilo per un singolo giocatore all'interno del grafico complessivo. A questo punto, seleziona solamente un giocatore e procedi con le formule.

Recuperiamo i dati per un singolo giocatore con la seguente formula:

=CERCA.X(CERCA.X(1;TBL_SUPPORTO[VALORE];TBL_SUPPORTO[GIOCATORI]);TBL_GIOCATORI[GIOCATORE];TBL_GIOCATORI[[VOTO]:[ASSIST]])

Praticamente cerchiamo il valore 1 nella colonna VALORE della tabella. Una volta trovato il valore, vogliamo cercarlo (in questo caso sarà il nome del calciatore) nella colonna GIOCATORE per poi restituire tutte le colonne da voto ad assist, come si nota da TBL_GIOCATORI[[VOTO]:[ASSIST]].

Vogliamo poi che vi sia un piccolo box per spiegare la tipologia di giocatore, indicando (se presenti) goal e assist. In questo caso recuperiamo la specifica per ogni singolo giocatore con una formula particolare:

=LET(player;CERCA.X(1;TBL_SUPPORTO[VALORE];TBL_SUPPORTO[GIOCATORI]);
PIÙ.SE(
E(W3>0;X3>0);CONCAT(player;" - ";W3;" Goal & ";X3;" Assist");
E(W3>0;X3=0);CONCAT(player;" - ";W3;" Goal");
E(W3=0;X3>0);CONCAT(player;" - ";X3;" Assist");
E(W3=0;X3=0);player))

La funzione LET permette di velocizzare i calcoli evitando di ripetere numerose volte le stesse informazioni. Dichiarando, in fase iniziale, che player è uguale a CERCA.X(1;TBL_SUPPORTO[VALORE];TBL_SUPPORTO[GIOCATORI]), posso evitare di scriverlo per ben 4 volte dato che la formula complessiva, senza LET, sarebbe la seguente:

=PIÙ.SE(
E(W3>0;X3>0);CONCAT(CERCA.X(1;TBL_SUPPORTO[VALORE];TBL_SUPPORTO[GIOCATORI]);" - ";W3;" Goal & ";X3;" Assist");
E(W3>0;X3=0);CONCAT(CERCA.X(1;TBL_SUPPORTO[VALORE];TBL_SUPPORTO[GIOCATORI]);" - ";W3;" Goal");
E(W3=0;X3>0);CONCAT(CERCA.X(1;TBL_SUPPORTO[VALORE];TBL_SUPPORTO[GIOCATORI]);" - ";X3;" Assist");
E(W3=0;X3=0);CERCA.X(1;TBL_SUPPORTO[VALORE];TBL_SUPPORTO[GIOCATORI]))

In questo caso usiamo la funzione PIÙ.SE che praticamente riassume i seguenti casi:

• Se il giocatore ha realizzato sia goal sia assist, vogliamo che ci siano entrambi
• Se il giocatore ha realizzato solo goal, vogliamo che siano indicati solo i goal
• Se il giocatore ha realizzato solo assist, vogliamo che siano indicati solo gli assist
• Se il giocatore non ha realizzato nè goal nè assist, vogliamo che ci sia solo il suo nome

Tornando alla formula precedente con LET, la funzione PIÙ.SE velocizza il processo dato che è come avere vari SE uno dopo l'altro, se non usassimo PIÙ.SE la formula sarebbe simile a questa:

=LET(player;CERCA.X(1;TBL_SUPPORTO[VALORE];TBL_SUPPORTO[GIOCATORI]);
SE(E(W3>0;X3>0);CONCAT(player;" - ";W3;" Goal & ";X3;" Assist");
SE(E(W3>0;X3=0);CONCAT(player;" - ";W3;" Goal");
SE(E(W3=0;X3>0);CONCAT(player;" - ";X3;" Assist");
SE(E(W3=0;X3=0);player)))))

Creare grafico a bolle con Excel, come iniziare

Riprendiamo il tema principale per la creazione di un grafico a bolle. In questo particolare grafico abbiamo bisogno di 3 dimensioni, nello specifico:

• X: qui inseriamo i valori per le ascisse (l’asse X è quello che si sviluppa in orizzontale)
• Y: qui inseriamo i valori per le ordine (l’asse Y che quello che si sviluppa in verticale)
• Dimensione della bolla: qui scegliamo il valore che preferiamo, la dimensione relativa determinerà quanto saranno grandi le singole bolle

Nel nostro caso, selezioniamo le colonne che ci interessano (da VOTO ad ASSIST) per i giocatori che abbiano più reti che assist. Da qui, clicchiamo su Inserisci > Grafici Consigliati > Tutti i grafici e andiamo a prendere i grafici a bolle (non in 3D):

Non ci preoccupiamo se la visualizzazione inizialmente sarà strana, clicchiamo su OK e andiamo avanti. A questo punto selezioniamo il grafico e andiamo su Struttura Grafico > Seleziona Dati > Serie1 > Modifica:

Come vediamo, i dati non sono quelli corretti dato che vorremmo avere:

• X: i valori dei goal (colonna I)
• Y: gli assist (colonna J)
• Dimensione della bolla: il voto medio (colonna H)

Modifichiamo quindi i riferimenti, inserendo anche il nome della serie (che è uguale alla cella G1 nel nostro caso).

NB: questo processo va ripetuto per tutte e 4 le serie, prima di continuare!

Per aggiungere gli altri dati, ci è sufficiente cliccare sul grafico > Seleziona Dati > Aggiungi. Ripetiamo la procedura per tutte le serie che ci interessano.

A questo punto, dovremmo avere un grafico simile a questo:

Siamo ancora lontani dalla versione finale, ma ci stiamo avvicinando.

Come cambiare i colori di un grafico a bolle su Excel

Riprendiamo questa visualizzazione per riprendere il concetto dei colori che vogliamo recuperare:

• I giocatori con più reti che assist devono avere la bolla rossa
• I giocatori con più assist che reti devono avere la bolla nera
• I giocatori con un numero uguale di reti e assist devono avere la bolla grigia

Non ci resta che selezionare il grafico, cliccare due volte sulle singole serie (su una singola bolla parte della serie) e modificare il riempimento:

Anche questo processo va ripetuto per tutte e 4 le serie. L'unica differenza, per la serie Focus, è che utilizzeremo il Riempimento a immagine con la seguente procedura:

• Riempimento > Riempimento a immagine
• Origine delle immagini > Inserisci
• Immagini online. Scegli pure l'immagine che ti piace di più!

Come modificare i dettagli di un grafico a bolle su Excel

Parliamo ora di alcuni dettagli del grafico a bolle, ad esempio vediamo che:

• C'è un titolo (riquadro rosso). Questo lo aggiungiamo da Struttura Grafico > Aggiungi elemento grafico > Titolo del grafico. Da qui possiamo formattarlo come preferiamo, io ho inserito anche il logo del Milan per migliorare la visualizzazione ma è un'immagine inserita direttamente sul grafico, non è parte del titolo
• Ci sono dei titoli degli assi. La procedura è la stessa di prima (a parte il Titolo del grafico che diventa Titoli degli assi) e anche in questo caso ho inserito due immagini con lo stesso colore accanto al titolo degli assi, non sono parte del titolo stesso. Ho fatto un test con i caratteri UNICODE ma purtroppo non cambiava il colore, quindi sono inseriti sopra il grafico
• C'è lo slicer creato in precedenza dalla tabella di supporto con una visualizzazione particolare. In questo caso, possiamo selezionare lo slicer (Filtro dei Dati) per poi andare su Stili filtro dati, c'è una piccola freccia chiamata Altro che ci permette di modificare lo stile del filtro come preferiamo. Come procedimento è un po' lungo, dato che dovremo fare vari test per scegliere come modificare lo stile al meglio, puoi sempre prendere spunto dal file della guida per modificare in autonomia alcuni aspetti specifici
• Gli assi sono tratteggiati, questo si modifica cliccando due volte sugli assi > Riempimento linea > Tipo tratteggio così abbiamo una maggiore coerenza a livello grafico, chiaramente possiamo anche modificare il colore

Vediamo poi gli ultimi due dettagli, ovvero il riquadro viola e quello verde che riassume i valori per il singolo giocatore.

Per inserire le linee tratteggiate per il singolo valore, dobbiamo seguire questa procedura:

• Selezioniamo la serie FOCUS. Selezioniamo il grafico, nella schermata di destra vediamo che c'è una sezione chiamata Opzioni dove possiamo poi, cliccando sulla freccia in basso, selezionare tutti gli elementi del grafico. In questo caso selezioniamo la serie FOCUS

• Clicchiamo poi su (lato sinistro dello schermo, da dove abbiamo aggiunto il titolo e gli altri elementi grafici) Aggiungi elemento grafico > Barre di Errore > Altre opzioni barre di errore. A questo punto dovremmo inserire unicamente la direzione Negativa per ognuna delle barre, inserendo poi il valore che ci interessa sia per i goal sia per gli assist. Questo è possibile cliccando su Personalizzato in basso, inserendo la cella che è relativa al singolo giocatore (ricavata dalla tabella SUBTOTALE creata in precedenza, nel nostro caso con i valori W3 e X3)

Per inserire invece il dettaglio con il numero di goal e assist, possiamo farlo sempre selezionando la serie FOCUS per poi cliccare su Aggiungi elemento grafico > Etichette dati > Sopra. Possiamo poi modificare la formattazione come preferiamo, l'aspetto importante è cliccare su Valore da celle e poi associare l'etichetta con il titolo che avevamo creato in precedenza con la funzione LET. In questo caso, il riferimento è alla cella V2.

Come creare un grafico a bolle su Excel - conclusione

Siamo arrivati alla fine della guida! Oltre a vedere come creare un grafico a bolle da zero, abbiamo poi aggiunto numerosi elementi grafici per migliorare la visualizzazione. Il suggerimento è sempre quello di prestare attenzione a quest'ultima parte, dato che anche analisi interessanti possono perdersi se non riusciamo a valorizzare ed evidenziare gli elementi che scopriamo in fase di analisi. In questo caso, modificare i colori delle bolle e creare un focus per un singolo giocatore ha sicuramente aggiunto alcuni elementi di valutazione, rispetto al rimanere su un livello più semplice con un solo colore e nessuna indicazione per l'utente.

Valuta sempre chi sia il tuo interlocutore - in questo caso ad esempio io confido che anche un non appassionato non avrà problemi a farsi un'idea su chi sia più offensivo o difensivo oppure chi sia più importante per le sorti della squadra, ma sarebbe stato molto complesso dare le stesse indicazioni con il primo grafico che abbiamo visto!

Mentre invece con quello finale, anche se le informazioni sono esattamente le stesse, riusciamo a raccontare una vera e propria storia: